bat批处理菜单手动静态ip或dhcp获取及重启网卡
1、在桌面新建“新建文本文档”，把下面“代码”复制进去。然后选择“文件”->“另存为”，(注：保存时旁边的编码类型选ANSI，不要选utf-8，否则在命令行中会乱码) 然后在文件名输入框处输入“网卡配置ip.bat”（注意后缀为“.bat”)，然后点击保存。注：该代码以windows 10笔记本为原型，可能其它设备有所不同，需要小做改动。主要为网卡的名字和开始的指令略微不同，需自行改动匹配自己的设备。
2、@ echo off
rem 关闭回显
title 网卡配置
rem 设置标题
color A
rem 设置字体颜色为绿色
rem --------------------------------------
%1 %2
ver|find "5.">nul&&goto :Admin
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :Admin","","runas",1)(window.close)&goto :eof
:Admin
rem -------------------------------------设置为管理员运行
GOTO MENU
:MENU
echo 本地网卡地址：
netsh interface ipv4 show config name="以太网"
rem -------显示当前ip设置
ECHO.
ECHO. =-=-=-=-=网卡配置批处理菜单=-=-=-=-=
ECHO.
ECHO. 1 网卡改为DHCP
ECHO.
ECHO. 2 手动修改ip地址
ECHO.
ECHO. 3 重启网卡
ECHO.
ECHO. 4 退 出
ECHO.
ECHO.
ECHO.
echo. 请输入选择项目的序号：
set /p ID=
if "%id%"=="1" goto cmd1
if "%id%"=="2" goto cmd2
if "%id%"=="3" goto cmd3
IF "%id%"=="4" exit
PAUSE
:cmd1
echo 自动获取ip地址....
netsh interface ipv4 set address name="以太网" source=dhcp
echo 自动获取DNS服务器....
netsh interface ipv4 set dnsservers name="以太网" source=dhcp
rem 适用于win10本地连接改为dhcp
echo 自动获取IP成功……
goto MENU
:cmd2
set a=
set b=
set c=
set d=
echo 不想输入的直接按回车设置为空，如dns地址不设
set /p a=请输入ip地址:
set /p b=请输入子网掩码:
set /p c=请输入默认网关:
set /p d=请输入dns服务器地址:
echo 正在设置固定ip地址.....
netsh interface ipv4 set address "以太网" static %a% %b% %c%
echo 正在设置固定dns地址......
netsh interface ipv4 set dnsservers "以太网" static %d% primary
echo 手动设置ip地址成功.........
GOTO MENU
:cmd3
echo 关闭网卡....
netsh interface set interface 以太网 disabled
echo 开启网卡....
netsh interface set interface 以太网 enabled
echo 网卡重启完成........
GOTO MENU
pause