Windows系统电脑设置时间经验汇总
1、HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\TimeProviders\NtpServer内的「Enabled」设定为1，打开NTP服务器功能
2、HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\Config\AnnounceFlags设定为5,该设定强制主机将它自身宣布为可靠的时间源
3、完成以上操作，重启windows time服务
1、介绍：自写的checktime服务，可以实现客户端对时功能。自定义对时WEB服务器地址，自定义对时间隔，具有很强的可靠性。下载地址：https://download.csdn.net/download/iceou/10472159
2、通过IIS搭建支持ASP.net的WEB服务器，把下载得到的time.aspx文件解压
放到可WEB访问的目录下，如http://192.168.xx.xx/time.aspx
3、安装checktime服务
把下载的文件解压到本地磁盘，如F:\aaa
打开命令提示符
'安装服务的代码：
'"%SystemRoot%\Microsoft.NET\Framework\v4.0.30319\InstallUtil.exe" F:\aaa\checktime.exe
'net start "服务名称"
'卸载服务的代码：
'net stop "服务名称"
'"%SystemRoot%\Microsoft.NET\Framework\v4.0.30319\InstallUtil.exe" /u F:\aaa\checktime.exe
4、修改服务的配置文件
服务的配置文件checktimeConfig.xml
timer_interval时间间隔，以毫秒为单位
time_url设置对时服务器地址，如http://192.168.xx.xx/time.aspx
5、目录下的error.log为服务日志文件，会定时清理
1、①现象：时间同步时出错，不同步，启动windows time服务，报系统错误1079：此服务的账户不同于运行于同一进程上的其他服务。
处理方法：windows time服务登录身份更改为LocalService方式。
2、②现象：时间同步时出错，报RPC错误，启动windows time服务时报错误1058:无法启动服务,原因可能是已被禁用与其相关联的设备没有启动。
处理办法：w32tm /register重新注册服务。
3、③时间相关分支注册表不能修改。处理办法：给予相关注册表分支足够的权限（如图，设置要点）
1、将以下内容复制，保存为“客户端对时批处理.bat”
@echo off
:menu
color 0a
cls
echo ========================================
echo # 对时功能 #
echo # 1- 执行服务器对时 #
echo # 2- 注册Windows Time服务 #
echo # 3- 反注册Windows Time服务 #
echo # 4- 启动Windows Time服务 #
echo # 5- 停止Windows Time服务 #
echo # 6- Exit #
echo ========================================
set /p id=请输入数字：
if "%id%" == "1" goto cmd1
if "%id%" == "2" goto cmd2
if "%id%" == "3" goto cmd3
if "%id%" == "4" goto cmd4
if "%id%" == "5" goto cmd5
if "%id%" == "6" exit ELSE (
echo 输入的序号 %id% 不能识别,请重新输入！
goto p
)
:cmd1
echo 脚本开始执行
echo --------------------------------
echo 1、设置NPT服务器地址
set myip=192.168.14.14
set /p myip=请输入NPT服务器地址(按回车键默认：192.168.14.14)：
REG ADD HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\DateTime\Servers /v 0 /t REG_SZ /d %myip% /f
REG ADD HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\DateTime\Servers /ve /t REG_SZ /d 0 /f
REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\Parameters /v NtpServer /t REG_SZ /d %myip%,0x9 /f
w32tm /config /manualpeerlist:%myip% /syncfromflags:MANUAL
echo 2、设置对时频率：
set freq=3600
set /p freq=对时频率(按回车键默认：3600)：
REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time\TimeProviders\NtpClient /v SpecialPollInterval /t REG_DWORD /d %freq% /f
echo 3、设置Windows Time服务自动执行
REG ADD HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services\W32Time /v Start /t REG_DWORD /d 2 /f
echo 4、停止Windows Time服务
net stop w32time
echo 5、启动Windows Time服务
net start w32time
echo 6、立即执行时间同步
set flag=0
set /p flag=立即执行(按回车键或0默认执行，1或其它数字不执行)：
if %flag% == 0 (goto sync) else (goto menu)
:sync
set opver=0
set /p opver=操作系统版本(按回车键或0默认WIN7，1为WINXP)：
if %opver% == 0 (w32tm /resync) else (net time /setsntp:%myip%)
goto p
:cmd2
w32tm /register
goto p
:cmd3
w32tm /unregister
goto p
:cmd4
net start w32time
goto p
:cmd5
net stop w32time
goto p
:p
pause
goto menu
2、右键以管理员身份运行刚保存的批处理文件，运行效果如图:
